DIY Simple Arduino Discharger for IMA battery

/*
  switchCase IMA discharger V3.2

  Code is based on the switch statement. The switch statement allows you
  to choose from among a set of discrete values of a variable. It's like a
  series of if statements.

  The circuit:
  - 4 resistor array between 0V and +5V (0V, 2.2k, 10k, 10k, 2.2k +5V works). 3 position selector switch to analog in 1 switches between the centre point and either side of the 10k resistors
  - A 100k trimming potentiometer goes across the IMA battery, set to 2500R on the 0V side and 97.5k on the +ve side. On a 0-200V scale, this creates a 0-5V range on the potential divider that the Arduino can read. Arduino pin A0 goes between 0V and the 2500R tap.

  Changes from switchCase IMA discharger V3.1:
  The following are to reduce the data output for improved data logging:
  1) Setup prints the switchCase IMA Discharger version to the Serial Monitor
  2) Changed the loop outputs to the Serial Monitor to a single csv formatted line (time,voltage) instead of 5 lines of text
  3) Changed the loop delay from ~1 second to 10 seconds to reduce data
  4) Added a loop counter for the 'time' field

  Original SwitchCase code by Tom Igoe and is in the public domain:

  http://www.arduino.cc/en/Tutorial/SwitchCase
*/

// these constants won't change. They are the lowest and highest readings you
// get from your sensor:
const int sensorMin = 0;      // sensor minimum, defined in original SwitchCase code
const int sensorMax = 900;    // sensor maximum, discovered through experiment (600 in original SwitchCase code)

const int DischargeOutput1 =  4;      // pin number for discharge output 1
const int DischargeOutput2 =  5;      // pin number for discharge output 2
const int FinishedLED =  6;      // pin number for finished discharging LED

int count = 0;

void setup() {
  // initialize serial communication:
  Serial.begin(9600);
  pinMode(DischargeOutput1, OUTPUT);
  pinMode(DischargeOutput2, OUTPUT);
  pinMode(FinishedLED, OUTPUT);
  digitalWrite(DischargeOutput1, LOW);
  digitalWrite(DischargeOutput2, LOW);
  digitalWrite(FinishedLED, LOW);
  Serial.println("switchCase IMA discharger V3.2");
  Serial.println("Time,Voltage");
}

void loop() {
  // read the sensor:
  int sensorReading = analogRead(A1);
  // map the sensor range to a range of three options:
  int range = map(sensorReading, sensorMin, sensorMax, 0, 2);

  // select discharge voltage depending on the range value:
  switch (range) {
    case 0:    // switch position is between 2.2k and 10k at 0V end of array, reads approx 0.45V
      // Discharge to 140V
      {
        // read the input on analog pin 0:
        int sensorValue = analogRead(A0);
        // Convert the analog reading (which goes from 0 - 1023) to a voltage (0 - 200V):
        float voltage = sensorValue * (200.0 / 1023.0);
        // print out data on one line for logging:
        Serial.print(count);
        Serial.print(",");
        Serial.println(voltage);

        // if the voltage value is high enough, turn on the discharge outputs:
        if (voltage > 145.0) {
          highDischarge();
        }
        else if (voltage > 140.0) {
          lowDischarge();
        }
        else {
          endDischarge();
          stopSketch();
        }
      }
      //delay(1000);
      break;

    case 1:    // switch position is at middle of array, reads approx 2.5V
      // Discharge to 120V
      {
        // read the input on analog pin 0:
        int sensorValue = analogRead(A0);
        // Convert the analog reading (which goes from 0 - 1023) to a voltage (0 - 200V):
        float voltage = sensorValue * (200.0 / 1023.0);
        // print out data on one line for logging:
        Serial.print(count);
        Serial.print(",");
        Serial.println(voltage);

        // if the voltage value is high enough, turn on the discharge outputs:
        if (voltage > 145.0) {
          highDischarge();
        }
        else if (voltage > 120.0) {
          lowDischarge();
        }
        else {
          endDischarge();
          stopSketch();
        }
      }
      //delay(1000);
      break;

    case 2:    // switch position is between 10k and 2.2k at 5V end of array, reads approx 4.55V
      // Discharge to 100V
      {
        // read the input on analog pin 0:
        int sensorValue = analogRead(A0);
        // Convert the analog reading (which goes from 0 - 1023) to a voltage (0 - 5V):
        float voltage = sensorValue * (200.0 / 1023.0);
        // print out data on one line for logging:
        Serial.print(count);
        Serial.print(",");
        Serial.println(voltage);

        // if the voltage value is high enough, turn on the discharge outputs:
        if (voltage > 145.0) {
          highDischarge();
        }
        else if (voltage > 100.0) {
          lowDischarge();
        }
        else {
          endDischarge();
          stopSketch();
        }
      }
      //delay(1000);
      break;

  }
  delay(10000);        // 10 second delay in between reads
  count = count+10;    // increment the time counter

}

void highDischarge() {
  digitalWrite(DischargeOutput1, HIGH);
  digitalWrite(DischargeOutput2, HIGH);
  //Serial.println("High rate discharge on");
  //Serial.println(" ");
}

void lowDischarge() {
  digitalWrite(DischargeOutput1, HIGH);
  digitalWrite(DischargeOutput2, LOW);
  //Serial.println("Low rate discharge on");
  //Serial.println(" ");
}

void endDischarge() {
  digitalWrite(DischargeOutput1, LOW);
  digitalWrite(DischargeOutput2, LOW);
  Serial.println("Discharge off");
  Serial.println(" ");
  Serial.println("Cycle finished, end of discharge");
  digitalWrite(FinishedLED, HIGH);
  delay(1000);
}

void stopSketch(void) {
  // this is used to stop the code indefinitely after discharging
  noInterrupts();
  while (1) {}
}